Торговый робот

Мы уже рассматривали код торгового робота, который получает OHLC по номеру свечи из графика. Но в первоначальном варианте этого кода, таймфрейм был ограничен 1 — 60 минутами, т.е. «часовками». Сейчас я переделал код, чтоб можно было получать длительные таймфреймы, в т.ч. «дневки» и «недельки» и даже, не побоюсь этого слова, «месячные»! Отличие — в блоке анализа переменной INTERVAL, и если она отрицательная (в случаях дневок и более) или больше 60 — меняется переменная таймфрейма подстановки в функцию получения данных свечи из графика, а переменная перебора времени та же самая. Функция готовая, ее можно использовать. Т.к. функция очень востребована, выкладываю в свободном доступе.

В QUIK выводи график цены, в виде баров или свечей, выбранного и прописанного в переменной INSTRUMENT в коде робота кода бумаги (код класса определяется автоматически). Значение переменной NUMBER — это номер свечи, OHLC которой нам нужно, а в переменной INTERVAL указываем активный таймфрейм на построенном графике, в соответствии с подсказкой. Вот что получаем:

Получение OHLC по номеру свечи из графика

Здесь показан торговый робот, у которого была задача найти котировки второй свечи на недельном графике. что он и сделал, и вывел в таблицу. Ну и текущее серверное время, до кучи

PORTFOLIO_EX OHLC2;
DESCRIPTION OHLC2;
CLIENTS_LIST ALL_CLIENTS;
FIRMS_LIST ALL_FIRMS;
USE_CASE_SENSITIVE_CONSTANTS;

PROGRAM

' НАСТРОЙКИ ТОЛЬКО ЗДЕСЬ!
INSTRUMENT="RIM0"
NUMBER=2 ' НОМЕР ИСКОМОЙ СВЕЧИ. ТЕКУЩАЯ = 1
INTERVAL=-2 ' ТАЙМФРЕЙМ НА ОТКРЫТОМ ГРАФИКЕ В МИНУТАХ. ВАЖНО!
' ЗНАЧЕНИЯ ПЕРЕМЕННОЙ INTERVAL ДЛЯ ТАЙМФРЕЙМОВ:
' 1 МИНУТА=1
' 2 МИНУТЫ=2
' 3 МИНУТЫ=3
' 4 МИНУТЫ=4
' 5 МИНУТ=5
' 6 МИНУТ=6
' 10 МИНУТ=10
' 15 МИНУТ=15
' 20 МИНУТ=20
' 30 МИНУТ=30
' 60 МИНУТ=60
' 2 ЧАСА=120
' 4 ЧАСА=240
' ДНЕВНОЙ=-1
' НЕДЕЛЬНЫЙ=-2
' МЕСЯЧНЫЙ=-3

' *************

'========= ПЕРЕМЕННЫЕ
CLASSCODE=GET_VALUE(GET_SECURITY_INFO("",INSTRUMENT),"CLASS_CODE") ' АВТОМАТИЧЕСКИ ПОЛУЧАЕМ КОД КЛАССА
OPEN=0 ' ЗАВОДИМ ПЕРЕМЕННЫЕ
HIGH=0
LOW=0
CLOSE=0

'========= ДАТА И ВРЕМЯ СЕРВЕРНОЕ
SERVERTIME=GET_INFO_PARAM("SERVERTIME")
SERVERDATE=GET_INFO_PARAM("TRADEDATE")
TIMESERV=SUBSTR(SERVERTIME,0,2)&SUBSTR(SERVERTIME,3,2)&SUBSTR(SERVERTIME,6,7)
HOUR=SUBSTR(TIMESERV,0,2)+0
MIN=SUBSTR(TIMESERV,2,2)+0
SEC=SUBSTR(TIMESERV,4,2)+0
TIME=TIMESERV+0
DATE=SUBSTR(SERVERDATE,6,4)&SUBSTR(SERVERDATE,3,2)&SUBSTR(SERVERDATE,0,2)
TRID=TIME&DATE

'========= КОНТРОЛЬ СОЕДИНЕНИЯ С СЕРВЕРОМ
IF IS_CONNECTED()<>1
RETURN
END IF

'========= ПОЛУЧАЕМ ДАННЫЕ СВЕЧЕЙ
OHLC(NUMBER) ' ВЫЗОВ ФУНКЦИИ
IF OPEN=0 OR HIGH=0 OR LOW=0 OR CLOSE=0
MESSAGE("НЕПРАВИЛЬНАЯ НАСТРОЙКА РОБОТА ИЛИ ГРАФИКА!",1)
RETURN
END IF

'========= ФУНКЦИИ
' OHLC
FUNC OHLC(NUMBER)
M=0
IF INTERVAL>60 OR INTERVAL<0
INTERVAL2=INTERVAL
INTERVAL=60
ELSE
INTERVAL2=INTERVAL
END IF
CURYEAR=GET_VALUE(GET_DATETIME(), "YEAR")
CURMONTH=GET_VALUE(GET_DATETIME(), "MONTH")
CURDAY=GET_VALUE(GET_DATETIME(), "DAY")
CURHOUR = GET_VALUE(GET_DATETIME(), "HOUR")
CURMIN = GET_VALUE(GET_DATETIME(), "MIN")
CURMIN = INTERVAL*FLOOR(CURMIN/INTERVAL)
N=(50*24) *(FLOOR(60/INTERVAL))
FOR I FROM 1 TO N
TEXTDATA=FTEXTDATA(CURYEAR,CURMONTH,CURDAY) &""
TEXTTIME=FTEXTTIME(CURHOUR,CURMIN) & ""
CANDLE=GET_CANDLE(CLASSCODE,INSTRUMENT, "", INTERVAL2 & "", "PRICE", TEXTDATA, TEXTTIME)
OPEN=GET_VALUE (CANDLE, "OPEN")+0
IF OPEN>0
M=M+1
IF M=NUMBER
OPEN=GET_VALUE (CANDLE, "OPEN")+0
HIGH=GET_VALUE (CANDLE, "HIGH")+0
LOW=GET_VALUE (CANDLE, "LOW")+0
CLOSE=GET_VALUE (CANDLE, "CLOSE")+0
I=N
INTERVAL=INTERVAL2
END IF
END IF
CURMIN=CURMIN-INTERVAL
IF CURMIN<0
CURMIN=60+CURMIN
CURHOUR=CURHOUR-1
IF CURHOUR<0
CURHOUR=23
CURDAY=CURDAY-1
IF CURDAY<1
CURDAY=31
CURMONTH=CURMONTH-1
IF CURMONTH<1
CURMONTH=12
CURYEAR=CURYEAR-1
IF CURYEAR<0
MESSAGE ("NO DATA",1)
END IF
END IF
END IF
END IF
END IF
END FOR
END FUNC

' ФУНКЦИЯ ПЕРЕВОДА ДАТЫ В ТЕКСТОВЫЙ ФОРМАТ
FUNC FTEXTDATA(YEAR,MONTH,DAY)
IF (LEN(MONTH) < 2)
MONTH = "0" & MONTH
END IF
IF (LEN(DAY) < 2)
DAY = "0" & DAY
END IF
RESULT = YEAR & MONTH & DAY
END FUNC

' ФУНКЦИЯ ПЕРЕВОДА ВРЕМЕНИ В ТЕКСТОВЫЙ ФОРМАТ
FUNC FTEXTTIME(HOUR,MIN,SEC)
IF (LEN(HOUR) < 2)
HOUR = "0" & HOUR
END IF
IF (LEN(MIN) < 2)
MIN = "0" & MIN
END IF
RESULT = HOUR & MIN & "00"
END FUNC

'========= ТАБЛИЦА
OUTPUT=CREATE_MAP()
OUTPUT=SET_VALUE(OUTPUT,"TIME",TIME)
OUTPUT=SET_VALUE(OUTPUT,"OPEN",OPEN)
OUTPUT=SET_VALUE(OUTPUT,"HIGH",HIGH)
OUTPUT=SET_VALUE(OUTPUT,"LOW",LOW)
OUTPUT=SET_VALUE(OUTPUT,"CLOSE",CLOSE)

DELETE_ALL_ITEMS()
ADD_ITEM(1,OUTPUT)

END_PROGRAM

PARAMETER TIME;
PARAMETER_TITLE ВРЕМЯ;
PARAMETER_DESCRIPTION ВРЕМЯ;
PARAMETER_TYPE STRING(30);
END

PARAMETER OPEN;
PARAMETER_TITLE OPEN;
PARAMETER_DESCRIPTION OPEN;
PARAMETER_TYPE NUMERIC(10,2);
END

PARAMETER HIGH;
PARAMETER_TITLE HIGH;
PARAMETER_DESCRIPTION HIGH;
PARAMETER_TYPE NUMERIC(10,2);
END

PARAMETER LOW;
PARAMETER_TITLE LOW;
PARAMETER_DESCRIPTION LOW;
PARAMETER_TYPE NUMERIC(10,2);
END

PARAMETER CLOSE;
PARAMETER_TITLE CLOSE;
PARAMETER_DESCRIPTION CLOSE;
PARAMETER_TYPE NUMERIC(10,2);
END
END_PORTFOLIO_EX

Торговый робот доступен в виде файла.