Торговый робот

Почему в стандартном QUIK нет встроенного индикатора ATR (Average True Range) — тайна покрытая мраком. Хотя разработчики давно обещают его сделать. Но думаю это временно и, наверное, в следующих ближайших версиях он появится. Но нам то работать надо уже сейчас, а не ждать когда он будет встроенным.

Для начала предлагаю освежить в памяти, что же такое ATR? Индикатор Average True Range — «средний истинный диапазон» был разработан Уэллсом Уайлдером, и предназначен для оценки размера предыдущих свечей — оценки волатильности. Изначально автор определил TR — True Range — Истинный диапазон, который определялся как самое большое из трех параметров:

1. разница между текущими HIGH и LOW;
2. модуль разницы между текущим HIGH и предыдущим CLOSE;
3. модуль разницы между текущим LOW и предыдущим CLOSE.

Средний истинный диапазон — ATR- ничто иное как простое среднее из TR за определенный период. Как правило используют периоды ATR от 12 до 14, чем выше его значение тем активнее торговля и больше вероятность резких движений. Считается что это неплохой индикатор для фильтрации флэта.

С теорией разобрались — переходим к практике. Как понятно из формулы расчета ATR, нам необходимо проанализировать OHLC такого количества баров, какой период ATR нам нужен. Для этого можно использовать проверенную функцию OHLC. Перед написанием расчета я поискал в сети и нашел готовую функцию расчета ATR, которая была сделана как раз на основе нашей функции OHLC! Воистину мир круглый! Отдельное спасибо товарищу DIM_TRADER, за разрешение публикации его функции. Автор акцентирует наше внимание на том, что функция выдает результат идентичный встроенному индикатору ATR в WLD (система технического анализа), что нас вполне устраивает:

FUNC FATR_COL (PERIODATR, INTERVAL, CLASSCODELIST, INSTRUMENT)
'***************************************************************************
' DIM-MARCH-2010  (DIM_TRADER.LIVEJOURNAL.COM И TD4LIVE.LIVEJOURNAL.COM)
' ПОСЛЕДНЯЯ КОРРЕКТИРОВКА, 19.03.2010.' УБРАНО ВСЕ ЛИШНЕЕ
'***************************************************************************
' ФУНКЦИЯ ДЛЯ РАСЧЕТА ATR
'
' PERIODATR - ПЕРИОД ATR В БАРАХ
' INTERVAL - ТАЙМ ФРЕЙМ ГРАФИКА
' CLASSCODE, INSTRUMENT - НАЗВАНИЕ ГРАФИКА С КОТОРЫМ РАБОТАЕМ И КОД КЛАССА
'
'***************************************************************************'
CANDLECOUNT=0
HIGH=0
LOW=0
CLOSE=0
RES=0
AVR_RES=0
DAYTOFIND=PERIODATR*50
CANDLETOFIND=PERIODATR
' СОЗДАЕМ ПРОМЕЖУТОЧНЫЕ МАССИВЫ
COL_HIGH=CREATE_COLLECTION()
COL_LOW=CREATE_COLLECTION()
COL_CLOSE=CREATE_COLLECTION()
CURYEAR=GET_VALUE(GET_DATETIME(), "YEAR")
CURMONTH=GET_VALUE(GET_DATETIME(), "MONTH")
CURDAY=GET_VALUE(GET_DATETIME(), "DAY")
CURHOUR = GET_VALUE(GET_DATETIME(), "HOUR")
CURMIN = GET_VALUE(GET_DATETIME(), "MIN")
CURMIN = INTERVAL*FLOOR(CURMIN/INTERVAL) ' ОКРУГЛЯЕМ МИНУТЫ ДО "ИНТЕРВАЛЬНЫХ"
' *** ОТЛАДОЧНАЯ ЗАПИСЬ В ФАЙЛ
'WRITELN ("CANDLE.LOG", CURHOUR& " "&CURMIN & "------------------------------------------------")
'WRITELN ("ATR.LOG", CURHOUR& " "&CURMIN & "------------------------------------------------")
FOR I FROM 1 TO DAYTOFIND   ' ПОИСК ПО ТАКОМУ КОЛИЧЕСТВУ СВЕЧЕК ГРАФИКА
'    ГОТОВИМ ПЕРЕМЕННЫЕ ДЛЯ ОБРАЩЕНИЯ К СВЕЧКЕ НА ГРАФИКЕ
TEXTDATA=FTEXTDATA(CURYEAR,CURMONTH,CURDAY) &""
TEXTTIME=FTEXTTIME(CURHOUR,CURMIN) & ""
'    ЧИТАЕМ СВЕЧКУ С ГРАФИКА
CANDLE=GET_CANDLE(CLASSCODELIST,INSTRUMENT, "", INTERVAL & "", "PRICE", TEXTDATA, TEXTTIME)
OPEN=GET_VALUE (CANDLE, "OPEN")+0
IF (OPEN>0)  ' Т.Е. ЕСЛИ СВЕЧКА СУЩЕСТВУЕТ И МЫ НЕ ВЫЛЕЗЛИ ЗА ДИАПАЗОН ТОРГОВ
CANDLECOUNT=CANDLECOUNT+1         ' ВЕДЕМ ПОДСЧЕТ ЭЛЕМЕНТОВ В МАССИВЕ
CLOSE=GET_VALUE (CANDLE, "CLOSE")+0  ' НУЖЕН НА ЭТОМ БАРЕ
HIGH=GET_VALUE (CANDLE, "HIGH")+0    ' НУЖНЫ НА СЛЕДУЮЩЕМ БАРЕ
LOW =GET_VALUE (CANDLE, "LOW")+0     ' НУЖНЫ НА СЛЕДУЮЩЕМ БАРЕ
' СОХРАНИТЬ В 3 МАССИВА ДЛЯ ДАЛЬНЕЙШЕЙ ОБРАБОТКИ
COL_HIGH  =INSERT_COLLECTION_ITEM(COL_HIGH,0,0)
COL_HIGH  =SET_COLLECTION_ITEM(COL_HIGH,0,HIGH)
COL_LOW   =INSERT_COLLECTION_ITEM(COL_LOW,0,0)
COL_LOW   =SET_COLLECTION_ITEM(COL_LOW,0,LOW)
COL_CLOSE =INSERT_COLLECTION_ITEM(COL_CLOSE,0,0)
COL_CLOSE =SET_COLLECTION_ITEM(COL_CLOSE,0,CLOSE)
'                 *** ОТЛАДОЧНАЯ ЗАПИСЬ В ФАЙЛ
'                ДАЛЕЕ - ВЕДЕМ ЖУРНАЛ (ДЛЯ ОТЛАДКИ)
'                WRITELN ("CANDLE.LOG", "CANDLECOUNT=" & CANDLECOUNT & " COL=" & GET_COLLECTION_COUNT(COL_HIGH) & " DATA=" & TEXTDATA & " TIME=" & TEXTTIME & "H=" & HIGH & "L=" & LOW & "C=" & CLOSE)
END IF
'            ОТКАТ НА "ИНТЕРВАЛ" НАЗАД
CURMIN=CURMIN-INTERVAL
IF CURMIN<0
CURMIN=60+CURMIN
CURHOUR=CURHOUR-1
IF CURHOUR<0
CURHOUR=23
CURDAY=CURDAY-1
IF CURDAY<1
CURDAY=31
CURMONTH=CURMONTH-1
IF CURMONTH<1
CURMONTH=12
CURYEAR=CURYEAR-1
IF CURYEAR<0
MESSAGE ("ОШИБКА! ФУНКЦИЯ FATR_COL. ОБНАРУЖЕН КОНЕЦ КОТИРОВОК",1)
END IF
END IF
END IF
END IF
END IF
END FOR
' НАЧИНАЕМ ИСКАТЬ TR И ДЕЛАТЬ MOVING AVERAGE
FOR I FROM 0 TO CANDLECOUNT-3  'ПОЧЕМУ 3: КОГДА ПИСАЛИ МАССИВЫ-НУМЕРОВАЛИ ОТ 1..., ТУТ C НУЛЯ (-1 ЯЧЕЙКА), ВЫКИНУЛИ ТЕКУЩУЮ (-1), ВЫКИНУЛИ ПРЕВУЮ СВЕЧКУ (У НЕЕ НЕТ CLOSE-1)
HIGH   =GET_COLLECTION_ITEM (COL_HIGH , I+1)    ' СЛЕДУЮЩАЯ ЗАПИСЬ
LOW    =GET_COLLECTION_ITEM (COL_LOW  , I+1)    ' СЛЕДУЮЩАЯ ЗАПИСЬ
CLOSE  =GET_COLLECTION_ITEM (COL_CLOSE, I)    ' ЭТА ЗАПИСЬ
'    ИЩЕМ МАКСИМУМ ИЗ 3-Х ВЕЛИЧИН
IF ABS(HIGH-LOW) > ABS(HIGH-CLOSE)
RES=ABS (HIGH-LOW)
ELSE
RES=ABS(HIGH-CLOSE)
END IF
IF ABS(LOW-CLOSE) > RES
RES=ABS(LOW-CLOSE)
END IF
'    ТЕПЕРЬ ДЕЛАЕМ MOVING AVERAGE, СЧИТАЕМ ATR ИЗ TR
IF I=0
AVR_RES=RES  'ВОТ ТУТ - ВАЖНО! ПЕРВЫЙ TR ПРОСТО РАВЕН HIGH-LOW !!! (СОГЛАСНО ПЕРВОИСТОЧНИКУ)
ELSE
AVR_RES=(AVR_RES*(CANDLETOFIND-1)+RES)/CANDLETOFIND
END IF
'     *** ОТЛАДОЧНАЯ ЗАПИСЬ В ФАЙЛ
'    WRITELN ("ATR.LOG", "I=" & I & " RES=" & RES & " AVR_RES=" & AVR_RES &" H(I)L(I)C(I-1)="&HIGH&" "&LOW&" "&CLOSE)
END FOR
RESULT = AVR_RES
END FUNC

Итак — промежуточный итог: у нас есть функция. Нужно нарисовать ее на графике. Здесь набросаем небольшой план наступления:

1. При первом старте нужно просчитать ATR на определенное кол-во баров назад, чтобы не ждать пока прорисуется весь график;
2. Новое значение наносим на график только с появлением новой свечи, чтоб не загружать систему;

Как рисовать на графике мы уже знаем — наносим метки с помощью функции ADD_LABEL. Метка — это графический-bmp файлик, с каким-то изображением, который мы помещаем в определенную точку на графике: ось X — время и дата нужной свечи, ось Y — значение ATR. Мы помним, что нанесение меток на существующий график возможно только по идентификатору, поэтому делаем следующее: создаем график цены нужной нам бумаги. Правой кнопкой по нему — добавить индикатор (например Elders Force Index) в новое окно. На вкладке «Дополнительно» в свойствах этого индикатора прописываем идентификатор BASE. чтоб наш робот увидел куда наносить метки. Затем делаем цвет линий этого индикатора таким же как фон. чтоб он нам не мешал. Поле подготовили. Теперь беремся за робота.

Тут все понятно: функция готовая, главная сложность это перебор баров назад для прорисовки предыдущих значений индикатора. Но и тут все просто: делаем цикл, и внутри него вызываем функцию ATR. Единственное нам пришлось чуть ее изменить. чтоб она сама возвращала время и дату свечи для каждого значения ATR. Итак — код:

Код торгового робота на QPILE доступен только зарегистрированным пользователям.

Как мы видим, метка рисуется файликом ATR_GRAPH.BMP, который должен храниться в той же папке что и сам робот. Мой файлик можно скачать тут. А можно нарисовать самостоятельно в Паинте:)

Все готово! Настраиваем и запускаем:

Индикатор ATR для QUIK

Да, чуть не забыл: у меня на 1 мин таймфрейме значение индикатора получилось в диапазоне 110-140, чтоб выглядело все красиво — двойной клик левой кнопкой по нижнему окну графика, и на вкладке «текущее окно диаграммы» в правом поле есть настройки правой оси. Укажите верхнюю и нижнюю границу так, чтоб было удобно читать индикатор. например: я поставил нижнюю границу=100 а верхнюю=250.

Удачи и боооольших профитов!